DEFINE COMPONENT PSD_E_monitor
DEFINITION PARAMETERS (nx=90, ny=90, nE=30, restore_neutron=0)
SETTING PARAMETERS (string filename=0, xmin=-0.05, xmax=0.05, ymin=-0.05, ymax=0.05, xwidth=0, yheight=0, Emin=1.0, Emax=50.0)
OUTPUT PARAMETERS (PSD_N, PSD_p, PSD_p2)
/* Neutron parameters: (x,y,z,vx,vy,vz,t,sx,sy,sz,p) */ 

DECLARE
  %{
    double PSD_N[nE][nx][ny];
    double PSD_p[nE][nx][ny];
    double PSD_p2[nE][nx][ny];
  %}
INITIALIZE
  %{
    int i,j,h;

    if (xwidth  > 0) { xmax = xwidth/2;  xmin = -xmax; }
    if (yheight > 0) { ymax = yheight/2; ymin = -ymax; }

    if ((xmin >= xmax) || (ymin >= ymax)) {
            printf("PSD_E_monitor: %s: Null detection area !\n"
                   "ERROR        (xwidth,yheight,xmin,xmax,ymin,ymax). Exiting",
           NAME_CURRENT_COMP);
      exit(0);
    }

    for (i=0; i<nx; i++)
     for (j=0; j<ny; j++)
       for (h=0; h<nE; h++)
       {
        PSD_N[h][i][j] = 0;
        PSD_p[h][i][j] = 0;
        PSD_p2[h][i][j] = 0;
       }
  %}
TRACE
  %{
    int i,j,h;
    double E;
    
    PROP_Z0;
    if (x>xmin && x<xmax && y>ymin && y<ymax)
    {
      E = VS2E*(vx*vx + vy*vy + vz*vz);
      h = floor( (E-Emin)*nE/(Emax-Emin) );
      if( h >= 0 && h < nE )
      {
        i = floor((x - xmin)*nx/(xmax - xmin));
        j = floor((y - ymin)*ny/(ymax - ymin));
        PSD_N[h][i][j]++;
        PSD_p[h][i][j] += p;
        PSD_p2[h][i][j] += p*p;
        SCATTER;
      }
    }
    if (restore_neutron) {
      RESTORE_NEUTRON(INDEX_CURRENT_COMP, x, y, z, vx, vy, vz, t, sx, sy, sz, p);
    }
  %}
SAVE
  %{
    int h;
    char newfilename[255];
    for(h=0; h<nE; h++)
    {    
      sprintf(newfilename, "%s_%i.dat", filename, h);
      DETECTOR_OUT_2D(
        "PSD_E_monitor",
        "X position [cm]",
        "Y position [cm]",
        xmin*100.0, xmax*100.0, ymin*100.0, ymax*100.0,
        nx, ny,
        &PSD_N[h][0][0],&PSD_p[h][0][0],&PSD_p2[h][0][0],
        newfilename);
    }
  %}

MCDISPLAY
%{
  magnify("xy");
  multiline(5, (double)xmin, (double)ymin, 0.0,
               (double)xmax, (double)ymin, 0.0,
               (double)xmax, (double)ymax, 0.0,
               (double)xmin, (double)ymax, 0.0,
               (double)xmin, (double)ymin, 0.0);
%}

END